Вопросы по Max Script (всего понемногу)

Stalker_Lomскрипт рабочий - но не у меня.

selection[1].bridgeSelected = 1
selection[1].EditablePoly.Bridge ()

$.bridgeSelected=1
$.EditablePoly.Bridge()

Stalker_Lomigorznag, к сожалению, что так, что так - ошибка та же.

do ($.EditablePoly.Bridge ()) or ($.EditablePoly.ConnectEdges ())

(
  $.modifiers[#Edit_Poly].ButtonOp #ConnectEdges
  if ($.modifiers[#Edit_Poly].bridgeselected != undefined) do
  (
    res = $.modifiers[#Edit_Poly].ButtonOp #BridgeEdge
  )
)

co=modPanel.getCurrentObject()
if classof co==Editable_Poly do
(
    es=polyop.getedgeselection co; oe=polyop.getOpenEdges co
    if (es*oe).numberSet>0 then co.Bridge () else co.ConnectEdges ()
)

if classof co==Edit_Poly do
(
    es=co.GetSelection #Edge; co.ConvertSelection #Edge #Border
    oe=co.GetSelection #Edge
    co.Select #Edge oe invert:true; co.Select #Edge es
    if (es*oe).numberSet>0 then co.ButtonOp #BridgeEdge
    else co.ButtonOp #ConnectEdges
)

igorznagПример:

co=modPanel.getCurrentObject()
if classof co==Editable_Poly do
(
    es=polyop.getedgeselection co; oe=polyop.getOpenEdges co
    if (es*oe).numberSet>0 then co.Bridge () else co.ConnectEdges ()
)

if classof co==Edit_Poly do
(
    es=co.GetSelection #Edge; co.ConvertSelection #Edge #Border
    oe=co.GetSelection #Edge
    co.Select #Edge oe invert:true; co.Select #Edge es
    if (es*oe).numberSet>0 then co.ButtonOp #BridgeEdge
    else co.ButtonOp #ConnectEdges
)

KoL'TЯ делал через проверку геометрии на изменение полигонов.

co=modPanel.getCurrentObject()
if classof co==Editable_Poly do
(
    if not co.Bridge() do co.ConnectEdges ()
)

if classof co==Edit_Poly do
(
    n1=co.GetNumFaces(); co.ButtonOp #BridgeEdge
    n2=co.GetNumFaces()
    if n2==n1 do co.ButtonOp #ConnectEdges
)

d1myanСупер! Спасибо)) уже 2й раз меня выручаете, не могу найти как - вам кармы добавить.
Я в максскрипте еще профан., но очень интересна эта тема.
С английским не дружу, нашел книгу на русском "Основы 3ds Max 8 Maxscript", Help - пытаюсь переводить в гугл переводчике.
Может вы посоветуете еще какую русскую литературу - с чего можно начать?

(
    for i = 0 to (layermanager.count - 1) do     -- loops through all the layers in the scene
    (
        x = layermanager.getlayer i              -- gets layer
        test = x.name as string                  -- applies the name of layer to test
        location = findString test "ref"         -- finds "ref" in layer name, output 1 if present
        if location == 1 do                      -- if ref is present in the layer name at the begining, 1 then
        (
        if x.on == true then x.on = false  -- the layer x is on, then turn it off
        else x.on = true                   -- the layer x is off, then turn it on. A toggle on/off really                     
        )                                   -- end if
    )                                            -- end loop
)

d1myanВозможно ли изменить: чтобы если некоторые включены- то он все выключил, а следующим нажатием все включил?

(
    layers_ref=#(); layers_ref_true_count=0
    for i = 0 to (layermanager.count - 1) do   
    (
        x = layermanager.getlayer i; test = x.name as string                 
        location = findString test "ref"       
        if location == 1 do                     
        (
            append layers_ref x; if x.on == true do layers_ref_true_count+=1
        )-- if location == 1 do                                 
    )-- for i = 0 to (layermanager.count - 1) do                                           
  
    for x in layers_ref do if layers_ref_true_count>0 then x.on=false else x.on=true
)

Просмотреть все слои
если в слое количество мешей  == 1
(
    переименовать меш по названию слоя
    переместить этот меш в нулевой слой
    удалить слой
)
    другое если количество мешей > 1
(
    в начале имени названию меша добавит название слоя
)
иначе (удалит слой)

for i = 0 to (layermanager.count - 1) do  
(
    _sl = layermanager.getlayer i
    _slname = _sl.name as string
    _slnode = _sl.getNumNodes()   
    if _slnode == 1 do                    
    (
        format "Layer: %; nodes: %\n" _slname _slnode
    )                      
)

WandererkzПривет. Как написать скрипт, который:
Просмотреть все слои
если в слое количество мешей == 1
(
переименовать меш по названию слоя
переместить этот меш в нулевой слой
удалить слой
)
другое если количество мешей > 1
(
в начале имени названию меша добавит название слоя
)
иначе (удалит слой)

for i = layerManager.count-1 to 1 by -1 do
(
    ilayer = layerManager.getLayer i
    layerName = ilayer.name
    layer = ILayerManager.getLayerObject i
    layer.nodes &layerObjects
  
    if layerObjects.count > 0 then
    (
        if layerObjects.count > 1 then
        (
            for o in layerObjects where not matchPattern o.name pattern:(layerName + "_*") do
            (
                o.name = (layerName + "_" + o.name)
            )
        )
        else
        (
            (layerManager.getLayer 0).addNode layerObjects[1]
            LayerManager.deleteLayerByName layer.name
        )
    )
    else
    (
        LayerManager.deleteLayerByName layer.name
    )
)

Владислав Бодюл

WandererkzСпасибо, прекрасно работает.

(layerManager.getLayer 0).addNode layerObjects[1]

layerObjects[1].name = layer.name