Упорядочить по алфавиту пункты меню

Собственно вопрос. Есть кастомный пункт меню куда кидаю частоюзаемые скрипты. Можно как-нить в авторежиме упорядочить там все по алфавиту...или только ручками?

Я так понимаю речь идёт о строке меню, там где Edit, Tools, Group...?

Вот например так:

! Перед выполнением лучше сделать бекап меню.

(
   fn compareStr s1 s2 = (stricmp s1[1] s2[1])   

   menuName = "....."
   menu = menuMan.findMenu menuName
   
   if menu != undefined do
   (
     menuItems = for i = 1 to menu.numItems() collect
     (
       item = menu.getItem i
       title = item.getTitle()
       title = trimLeft title "&";
       #(title,item)
     )

     qsort menuItems compareStr

     while menu.numItems() > 0 do
     (
       menu.removeItem (menu.getItem 1)
     )

     for i in menuItems do
     (
       menu.addItem i[2] -1
     )

     menuMan.updateMenuBar()
   )
)

Но только запускать придётся вручную, или кинуть в папку startup, и оно будет сортировать само при каждом запуске макса.
В строке menuName = "....." вместо точек нужно написать название своего меню.

BGA rullezz
Спасибо...все работает