Render.ru

Скрипт... кидает на рендер защиту-дождик...

Ironix

Активный участник
#2
женяс
Если я правильно понял что ты искал...
Вот собрал в виде эффекта... накидывает косые линии на рендеренное изображение...
в 2010 работает, думаю в 2009 тоже заведется...

Код:
plugin renderEffect RainProtection

name:"Rain Protection"

classID:#(0x78d891c8, 0x407a49b0)

(

    parameters main rollout:params
    (
        p_Color type:#color default:black ui:UI_Color
        p_Opacity type:#integer animatable:true ui:UI_Opacity default:128.0
        p_Step type:#integer animatable:true ui:UI_Step default:5.0
    )

    rollout params "Rain Protectection Parameters"
    (
        colorpicker UI_Color "Lines Color: " across:3
        spinner UI_Opacity "Opacity: " type:#integer range:[0,255,128] offset:[8,3]
        spinner UI_Step "Step: " type:#integer range:[1,100,5] offset:[0,3]
    )

    on apply bmp do
    (
        local step = p_Step
        local col = p_Color
        col.alpha = p_Opacity
        local shift = 0
        for h=0 to (bmp.height-1) do
        (
            local sline = getPixels bmp [0,h] bmp.width
            for i=1+shift to sline.count by step do sline[i] = composite col sline[i]
            setPixels bmp [0,h] sline
            if shift<step-1 then shift+=1 else shift = 0
        )
    )

)
 
Последнее редактирование:
Сверху